投資クラゲとは？どんなトレードをしているの？
こんにちは。「再現性のあるトレード方法」を習得した投資クラゲです。
現在は、資産を2倍の2倍、つまり合計4倍を達成しています。
主な投資対象は、ドル円、ユーロドル、ポンドドルの3つ。
トレードスタイルは、
◆スイングトレード（2日～20日間保有）
◆トレンドフォロー（21日～90日間保有）
下の画像のようなトレードをしています。
資産運用をシミュレートするにはエクセル関数を使うのが分かりやすいです。
エクセルを使えば、難しい計算を一瞬でやってくれます。
一度計算式を入れてしまえば、そのあとは数値を入力するだけで自動的に計算してくれます。
これがエクセル関数のすごいところです。
エクセル大先生、さまさまです。
FXは究極「確率論」、勝率〇％の世界です。
例えば、次のような計算を一瞬でやってくれます。
ドル円が各市場ごとにどれくらいのpips動いているのか知りたい
資産が1%ずつ増えていくとどのように資産が推移するのか知りたい
勝率60%のときに100回トレードをすると資産がどのように推移していくのか知りたい
さらに1000回トレードしたら？10000回トレードしたら？
毎日10pips獲得したら、資産がどのように増えていくのか知りたい
Lotは固定させた方がいい？変えた方がいい？
損失許容率はどれくらいがいいの？
このような計算はエクセルで簡単に計算できます。
これから紹介するエクセル関数は、資産運用のシミュレートだけではなく、他の場面でもきっと役立つでしょう。
- 家計簿をエクセルでつけていく（自分の収入、支出を見える化する）
- 仕事の効率化を図る（エクセル関数で業務効率化）
エクセル関数は覚えておいて損はありません。
今回は「資産運用についてシミュレートするときに役立ったエクセル関数ベスト13」と「資産運用をシミュレートする７つの方法」について深堀りしていきます。
今回は、資産運用についてシミュレートするときに役立ったエクセル関数ベスト13を、具体例とともに紹介します。
計算式も紹介するのでよかったらエクセルで実際にやってみてください！！
資産がどのように増えていくのか具体的にイメージできるようになります。
- 資産運用についてシミュレートするときに役立ったエクセル関数ベスト13
- 平均値、中央値、最大値、最小値を使って、市場ごとの値幅の大きさを捉える
- 【１％のすごさ】かけ算を使って、資産の推移をイメージする
- 【勝率60%のすごさ】かけ算を使って、資産の推移をイメージする
- 【10pipsのすごさ】1日10pipは将来とんでもないことになるという話。
- 【ランダム関数】勝率60%のときの資産の推移をシミュレートする 1000回、10000回トレードしたらどうなる？
- 【Lotの考え方】Lotを固定した場合とLotを資産の割合で変動させた場合の違いをシミュレートする
- 【なぜ損失許容率は2%なの？】勝率とリスクの関係をエクセルでシミュレートする
- まとめ 「複利の力」はエクセルで見える化する
資産運用についてシミュレートするときに役立ったエクセル関数ベスト13
それでは早速ベスト13を発表します。
これです！！
| 順位 | エクセル関数 | 役割 |
| 1 | 四則演算 =1+1 =1-1 =1*1 =1/1 | エクセル関数を使うときには必ず頭に「=」をつける 計算式には数値も入れることができるし、セルを選択することもできる 「+」…足し算の結果を求める 「-」…引き算の結果を求める 「*」…かけ算の結果を求める 「/」…わり算の結果を求める |
| 2 | =SUM(数値) | 数値の合計を求める |
| 3 | =AVERAGE(数値) | 数値の平均値を求める |
| 4 | =MEDIAN(数値) | 数値の中央値を求める 中央値とはデータの真ん中の値ということ データの中に大きく外れた値があるときに平均値だとその値に影響されてしまうが、中央値ならちょうど真ん中の数値を把握できる |
| 5 | =MAX(数値) | 最大の数値を求める |
| 6 | =MIN(数値) | 最小の数値を求める |
| 7 | =RAND() | 0~1のランダムな数値を返す ランダムな数値を使ってシミュレートしたいときに使う |
| 8 | =ABS(数値) | 数値の絶対値を返す 絶対値とは、数値から符号（+や-）を除いた数そのものの大きさのこと |
| 9 | =IF(論理式,真の場合,偽の場合) | 「もしも…の場合はA、…の場合はB」と値を変えることができる 例えば、勝ったら「1000」、負けたら「-1000」などを求めることができる |
| 10 | =ROUND(数値,桁数) | 指定した桁数までを表示するように四捨五入する |
| 11 | =10^2 | ^（キャレット）を使うと〇条を計算することができる 10^2は、10の2乗で100になる =POWER(数値,指数)関数を使っても求められる |
| 12 | =COUNT(範囲) =COUNTA(範囲) =COUNTIF(範囲,検索条件) =COUNTBLANK(範囲) | COUNT…数値を含むセルの個数を求める COUNTA…空白ではないセルの個数を求める COUNTIF…条件に当てはまるセルの個数を求める COUNTBLANK…空白のセルの個数を求める 例えば、勝敗を「〇」と「×」で入力していた場合、勝率を求めるときにCOUNTIFを使えば「〇」と「×」の個数を一瞬で計算してくれる |
| 13 | =INDEX(範囲,行番号,列番号) | 範囲の中の指定された行と列が交差する位置にあるセルを返す 例えば、100回トレードした結果は？1000回トレードした結果は？という100回目、1000回目のデータを取り出すときに使える |
今回は、この関数を使って具体的に資産運用をシミュレートします。
７つの方法を紹介するので、ぜひ取り組んでみてください。
平均値、中央値、最大値、最小値を使って、市場ごとの値幅の大きさを捉える
一日の市場は大きく分けて３つあります。
東京市場 9:00～15:00
ロンドン市場 15:00～21:00
ニューヨーク市場 21:00～24:00
かりに３つの市場を上記のような時間で区切ってみます。（正確に考えると違いますが、分かりやすく6時間、6時間、3時間としました。）
この３つに区切ったときに、ドル円の値動きが大きいはどこの時間帯でしょうか。
市場ごとの値幅がどれくらいあるのか分かれば、狙うpipsの検討がつきます。
エクセルに入力して考えてみましょう。
| 平均値 | =AVERAGE(C4:C23) | =AVERAGE(D4:D23) | =AVERAGE(E4:E23) |
| 中央値 | =MEDIAN(C4:C23) | =MEDIAN(D4:D23) | =MEDIAN(E4:E23) |
| 最小値 | =MIN(C4:C23) | =MIN(D4:D23) | =MIN(E4:E23) |
| 最大値 | =MAX(C4:C23) | =MAX(D4:D23) | =MAX(E4:E23) |
よかったらコピーして使ってください。
FXの分析で特におすすめなのは「中央値」です。
外れ値を除いて真ん中の値を求めることができるので便利です！！
通貨ペアはドル円。期間は2023年3月27日（月）～2023年4月21日（金）。
トレーディングビューでドル円を表示し、インジケーターで時間帯別に色分けして表示したあと、トレーディングビューの「ものさし」機能を使ってpipsをはかってエクセルに入力しました。
ものさし機能は正確ではありませんが、各市場ごとの特徴はつかめるかと思います。
東京市場、ロンドン市場、ニューヨーク市場を色分けしたかったら、「Time sessions for FXCM」というインジケーターがおすすめです。
平均値、中央値、最小値、最大値を計算して、次のようなことが分かりました。
時間帯による優位性を見つけることができます。
これだけでもかなり大きな収穫ですが、さらにデータを分析してみます。
このデータをさらに分かりやすく分析してみましょう。
せっかく時間帯別にデータを集めたので、今度は50pips以上動いた日が何パーセントかを求めます。
| すべての回数 | =COUNT(C4:C23) | =COUNT(D4:D23) | =COUNT(E4:E23) |
| 50pips以上の回数 | =COUNTIF(C4:C23,”>=50″) | =COUNTIF(D4:D23,”>=50″) | =COUNTIF(E4:E23,”>=50″) |
| 50pips以上の割合 | =C25/C24*100 | =D25/D24*100 | =E25/E24*100 |
まず、「すべての回数」をCOUNT関数で数えています。
そして、COUNTIF関数を使って「50以上のとき」の条件にあうセルの個数をカウントしています。
最後に、「50pips以上の回数」を「すべての回数」で割ります。
東京市場は55%の確率で50pips以上になります。
ロンドン市場は65％の確率、ニューヨーク市場は80%の確率です。
この結果から市場がオープンしてから50pips動いていないときは、チャンスだと考えることができます。
特にロンドン市場、ニューヨーク市場は値幅を狙うことができます。
せっかく計算式を作ったので、10pips以上のとき～100pips以上のときの確率も調べてみます。
先ほどのエクセル関数を応用すればすぐに計算できます。
この結果から、次のようなことが分かります。
時間帯による優位性が分かっていると、かなり有利にトレードをすることができます。
例えば次のような感じで考えることができます。
- 「まだロンドン市場で20pipsしか動いていないから、上か下どちらかに20pips以上動くことが考えられる。」
- 「ニューヨーク市場の時間帯に経済指標の発表があった。100pips以上動いたから、これ以上伸びないかもしれない。ある程度の戻しをつける可能性がある。」
- 「東京市場、ロンドン市場でそれぞれ80pipsくらい動いたから、ニューヨーク市場ではあまり動きがないかもしれない。」
時間帯による優位性は確実にあります。
時間帯によって戦略を使い分けられるようになりましょう！！
このように、各市場ごと値幅の目安を考えながらトレードすることができます。
今回は通貨ペアをドル円、期間を2023年3月27日（月）～2023年4月21日（金）として設定しましたが、期間や通貨ペアを変えて分析してみると面白い結果が得られます。
例えば、通貨ペアはそのままドル円で期間を１年間にするとかなり精度が高いデータを得ることができます。
通貨ペアをドル円以外でやってみるとドル円とは違う発見があり、ドル円よりも値幅が狙える通貨ペアや、あまり値幅が狙えない通貨ペアが分析によって明らかになります。
【１％のすごさ】かけ算を使って、資産の推移をイメージする
今度は資産が増えていくイメージをエクセルで計算していきます。
資産運用では「複利」という考え方が非常に重要になってきます。
これを知っていると知らないのとでは、雲泥の差が出てしまいます。
「複利」については下記の記事で詳しく解説しているので、よかったらどうぞ！！
複利とは簡単に言うと次の３つの言葉から説明することができます。
元本…もともとの資金
利子…元本に対して増える資金
複利…最初の元本だけでなく利子が利子を生み出すこと
資産運用は、まさに「複利」の力を使ってできることです。
例えばの話、次の２つだったらどちらを選びますか？
A １日１万円もらえる
B 毎日資産が１％増える（１万円スタート）
この場合は、もらえる期間によってどちらが得なのか、結果が変わってきます。
この問題の結果をエクセルで計算してみましょう。
| 1日1万円 | Aの合計 | 毎日資産が 1%増える | Bの合計 | |
| 1日目 | 10000 | =B2 | 10000 | =D2 |
| 2日目 | 10000 | =C2+B3 | =D2*1.01 | =D3 |
| 3日目 | 10000 | =C3+B4 | =D3*1.01 | =D4 |
3日目を下に1095日目までコピーします。
今回の計算は四則演算を使います。
足し算は「+」、引き算は「-」、かけ算は「*」、わり算は「/」で求めることができます。
１年目ではAの方が資産がたくさんあります。
２年目の途中にBが抜かして３年たつ頃には、Aは1095万円、Bは5億3405万1228円になっています。
BはAの約50倍になっていることが分かります。
つまり、投資家として毎日１％の資産を増やすことができれば３年後に億トレーダーになれるということです。
「毎日１％を継続的に」となるとかなりハードルが高いですが、勝率や損失許容率などを考慮した上で3年後、5年後に資産を10倍以上にすることは、かなり現実味がある話です。
【勝率60%のすごさ】かけ算を使って、資産の推移をイメージする
次はもう少し具体的に考えてみます。
投資家は資産をたし算ではなくかけ算で増やしていきます。
具体的には１回のトレードで資産を2%くらい増やすというイメージです。
利益になるトレード → 資産×1.02
しかし、投資していると失敗することもあります。（逆方向にいって損失を出すことを損切と言います。）
損切の場合は2%減るのと同じなので、つまり資産を×0.98するということです。
損失になるトレード → 資産×0.98
勝率については一概に〇％と断定することはできませんが、ここでは仮に勝率60%だったとしたらどうなるかを考えてみます。
勝率60%とは簡単に言えば10回勝負して6回勝って4回は負けることです。
勝率60% → 10回勝負したら6回勝って4回負ける
エクセルでは、「勝ち→負け→勝ち→負け→勝ち→負け→勝ち→負け→勝ち→勝ち→」を繰り返していきます。
勝率60%でトレードをすると資産がどのように推移していくのか、エクセルで計算してみましょう。
- 初期資金 10000円
- 損失許容率2%
- 勝率60%を５年間続ける（1年間=200日で計算）
| トレード日数 | 損失許容率2% | 資産の推移 |
| 1日目 | 1.02 | =10000*B2 |
| 2日目 | 0.98 | =C2*B3 |
| 3日目 | 1.02 | =C3*B4 |
| 4日目 | 0.98 | =C4*B5 |
| 5日目 | 1.02 | =C5*B6 |
| 6日目 | 0.98 | =C6*B7 |
| 7日目 | 1.02 | =C7*B8 |
| 8日目 | 0.98 | =C8*B9 |
| 9日目 | 1.02 | =C9*B10 |
| 10日目 | 1.02 | =C10*B11 |
10日目までを下に1000日目までコピーします。
今回の計算は四則演算のかけ算を使います。
かけ算は「*」で求めることができます。
勝率60%を毎日続けていくと、200日目に資産が約2倍になります。
400日目、600日目、800日目には、4.5倍、9.7倍、20.9倍と倍に倍に増えていきます。
といことはつまり…
勝率60%を５年間キープしていれば、資産が約44倍になります。
資産が約44倍ってすごくないですか！！？
これが勝率60%の力です。
今回は初期資金を１万円として計算していますが、もしこれが100万円、300万円スタートだったら？と考えると、勝率60%がかなりすごいことだということがお分かりいただけるかと思います。
「勝率80%～90％をキープし続ける」となれば、プロトレーダーでも難しいでしょう。まさに神の領域です。
当然、毎日勝率60%を続けるのはかなり難しい話ですが、絶対無理な話ではありません。
むしろ、勝率80%や90%よりもよほど現実味のある話です。
【10pipsのすごさ】1日10pipは将来とんでもないことになるという話。
今度はpipsという単位を使って計算してみましょう。
FXには次のような単位が使われます。
pips…「percentage in point」の略で、通貨ごとの共通単位のこと
Lot…通貨を買ったり売ったりするときの最低取引単位のこと
この２つはどれくらいの値幅のことを言っているのか、どれくらいの資金の大きさになるのか瞬時にイメージできるようにしておくといいです。
詳しくは以下の記事で解説しています。
円が絡む通貨ペア、例えばドル円、ユーロ円、ポンド円、オージー円などは、1pips=0.01円（1銭）を表しています。（各証券会社によって違いがあり、1pips=0.01円のことが多いです。）
1pips=0.01円（1銭）
10pips=0.1円（10銭）
100pips=1円（100銭）
pipsと同じくらい大事な単位としてLotという単位もあります。
Lotの計算は各証券会社によって違いがあり、1Lot=1000単位、1Lot=10000単位のものが多いです。
例えば、僕が使っているDMMFXでは、1Lot=10000単位となっています。
ドル円を1Lot買うということは、10000ドルを買うということです。
つまり、1ドル=100円のレートだった場合は、100万円を10000ドルに変えているということになります。
このとき1pips動いて1ドル=100.01円になったとします。
もっている10000ドルを売ると1000100円になります。
つまり、1Lotで取引したときに1pip動いた場合は100円動くということです。
表にすると次のような感じになります。（DMMFXの場合）
| 1pip（0.01円） | 10pips（0.1円） | 100pips（1円） | |
| 1Lot | 100円 | 1000円 | 10000円 |
| 10Lot | 1000円 | 10000円 | 100000円 |
| 100Lot | 10000円 | 100000円 | 1000000円 |
このpipsとLotの計算が瞬時にできるとトレードしやすくなります。
「平均値、中央値、最大値、最小値を使って、市場ごとの値幅の大きさを捉える」ではドル円が市場ごとにどれくらいのpips動くのかを調べました。
もう一度、結果を見てみましょう。
この結果から、東京市場では50pipsくらい、ロンドン市場では60pipsくらい、ニューヨーク市場では80pipsくらい動くことが分かりました。
毎日、この値幅の10pipsを取ることができればFXで生活していくことが充分に可能です。
えったった10pipsでいいの！！？
そう思う方もいるかもしれません。
というか、結論から言うと毎日10pipsを積み重ねれば億トレーダーになれます。
それぐらい「10pips」は価値のあることです。
では、毎日10pipsを獲得したら、実際の資産がどのように推移していくのかをエクセルで計算したいと思います。
今回は初期資金を100000円スタートで考えていきます。
Lotは損失許容率2%から計算して毎回変えていきます。
- 初期資金 100000円
- 損失許容率2%（スタートは2Lot、最大Lotを100Lotとして計算していきます。）
- 毎日10pipsを５年間続ける（1年間=200日で計算）
| 損失許容額 | 初期資金 | 100000 | ||
| 2% | =E3/E2 | =E2*0.02 | ||
| 日数 | Lotを計算 するための値 | Lot | 利益 | 資産の推移 |
| 1 | =E2/50000-0.5 | =ROUND(B5,0) | =C5*1000 | =E2+D5 |
| 2 | =E5/50000-0.5 | =ROUND(B6,0) | =C6*1000 | =E5+D6 |
| 3 | =E6/50000-0.5 | =ROUND(B7,0) | =C7*1000 | =E6+D7 |
3日目を下方向に1000日目までコピーすればOKです。
今回は、適正Lotを割り出すために「Lotを計算するための値」をあらかじめ計算しておく必要があります。
この適正Lotと「Lotを計算するための値」は、損失許容率から考えています。
例えば、初期資金100000万円だった場合、損失許容率は2%なので、損失は2000円までOKということになります。
損失とは反対に利益は2000円になります。（リスクリワードのことは触れていないので、仮に１：１とした場合で考えていきます。）
毎日10pipsプラスになるということは、利益がプラス2000になると考えます。
100000万円で10pips動いたときにプラス2000円になるには2Lotが必要です。
| 1pip（0.01円） | 10pips（0.1円） | 100pips（1円） | |
| 1Lot | 100円 | 1000円 | 10000円 |
| 10Lot | 1000円 | 10000円 | 100000円 |
| 100Lot | 10000円 | 100000円 | 1000000円 |
この表で考えれば2Lotで10pipsのときに利益が2000円になることが分かります。
この「2」という値を出すために、「資産/50000-0.5」という計算をします。
これは計算してみると、資産が100000円のときは100000/50000-0.5=1.5となります。
最終的にLotのところにあるROUND関数を使って、小数を四捨五入して整数にしています。
「Lotを計算するための値」が1.5になるときは、四捨五入されて適正Lotが「2」になります。
2Lotになるためには「Lotを計算するための値」が1.5～2.4になる必要があるので、それを逆算すると100000/50000-0.5=1.5という計算になります。
2Lotから3Lotになるタイミングは資産が150000円になったときです。
計算式に当てはめると150000/50000-0.5=2.5となって、四捨五入すると3になります。
このように「Lotを計算するための値」をあらかじめ計算しておけば適正Lotを割り出すことができます。
また、適正Lotは初期資金と損失許容率によって変わってきます。
損失許容率を2%から上げていくことで、多くの利益を狙っていくことも可能です。
ただ、その場合は損失も大きくなるので注意が必要です。
適正Lotの計算は少し複雑ですが、かなり重要な考え方です。
別の記事で触れていますが、Lotを固定させた場合とLotを変動させた場合で、資産の推移が大きく違ってきます。
この記事で固定Lotと変動Lotについて本気考察しています。
固定させた場合と変動させた場合で比べると、めちゃくちゃ違いがあります！！
知っておいて損はありません。
Lotを計算するために少しややこしい手順がありますが「エクセルに入力した計算式」の中で詳しく解説していますので、知りたい方はそちらをどうぞ。
20日目、約１ヵ月で資産が100000円から140000円になっています。
40000円プラスという結果ですが、資産が1.4倍になっているという点がめちゃくちゃすごいです。
この資産1.4倍が、後々から効いてきます。
20日目以降の資産の推移を見てみましょう。
エクセルの表が下まで入らないので、ポイントとなる日数のみ表示してあります。
100日目、約半年後には584000円になっています。100000円あった資産が約5.8倍になっています。
129日目、資産は100万円を突破。
200日目、資産は407万円に。
そして、212日目に最大の100Lotまで到達します。
その後、１年間に2000万円のペースで増えていることが分かります。
これが１日10pipsの威力です。
めちゃくちゃすごくないですか！！？
【ランダム関数】勝率60%のときの資産の推移をシミュレートする 1000回、10000回トレードしたらどうなる？
今度はもっと実践的なシミュレートをしてみましょう。
実際のトレードでは勝ったり負けたりを繰り返していきます。
厳密に言えば勝率60%とは、「10回勝負して6回勝って4回負ける」ということではなく、「毎回60%の確率で勝つ」ということです。
そこで今回は、ランダム関数を使ってシミュレートします。
ランダム関数を使えば、毎回ランダムに60%の確率で〇×を出力してくれます。
ランダムということは、２連勝や２連敗も当然あり得ます。
もしかすると、10連勝や10連敗もあるかもしれません。
それが確率の世界です。
仕組みだけ簡単に解説しておくと、こんな感じです。
ランダム関数を使って0～1の数字を作る
この作った数字を100倍して0～100の数字にする
もし、その数字が40以上だったら〇、40未満だったら×にする。（これがつまり勝率60%の仕組み）
勝率60%を積み重ねていくと、どのように資産は増えていくのでしょうか。
もしかすると連敗して破産する確率も０ではないかもしれません。
そのあたりも含めながらエクセルでシミュレートしてみたいと思います。
初期資金 100000円
損失許容率2%(スタートは2Lot、最大Lotを100Lotとして計算していきます。）
リスクリワード１：１
勝率60%をエクセルのランダム関数で求めて10000回繰り返す
結果はこんな感じです。
| リワード | 1000 | 勝率 | 60% | 初期資金 | 100000 | |
| リスク | -1000 | 勝ち | 60 | 損失許容率 | 0.02 | |
| 40 | 損失許容額 | =G1*G2 | ||||
| 回数 | ランダム | 勝敗 | リスク リワード | Lot計算に 必要な値 | 適正Lot | 合計資産 |
| 1 | =RAND()*100 | =IF(B6>=$D$3,”〇”,”×”) | =IF(C6=”〇”,$B$1,$B$2) | =ROUND(G1/50000-0.5,0) | =IF(E6>=100,100,E6) | =G1+D6*F6 |
| 2 | =RAND()*100 | =IF(B7>=$D$3,”〇”,”×”) | =IF(C7=”〇”,$B$1,$B$2) | =ROUND(G6/50000-0.5,0) | =IF(E7>=100,100,E7) | =G6+D7*F7 |
| 3 | =RAND()*100 | =IF(B8>=$D$3,”〇”,”×”) | =IF(C8=”〇”,$B$1,$B$2) | =ROUND(G7/50000-0.5,0) | =IF(E8>=100,100,E8) | =G7+D8*F8 |
3回目を下に10000回目までコピーすればOKです。
今回はランダム関数を使っています。
「ランダム」の列では、ランダム関数を使って数字を作り出しています。
まず=RAND()で0～1の値を作ります。
次に*100をして0～100の数にしています。
「勝敗」の列では、IF関数を使っています。
もしBの列が40以上だったら〇、それ以外だったら×という内容です。
その次の「リスクリワード」では、もし〇だったらリスクリワードのもとになる値1000を、もし×だったらリスクリワードのもとになる値-1000を表示させるようにしています。
「Lot計算に必要な値」では、資産/50000-0.5をして四捨五入しています。
これで適正Lotが計算できます。
「適正Lot」の列では、Lotがもし100以上になってしまった場合は100にする、それ以外はもとの数字にするという内容です。
「合計資産」の列では、資産にリスクリワード*Lotの値を足しています。
以上の内容を繰り返すことで、シミュレートが簡単にできるようになります。
結果は100トレードで1.18倍、1000トレードで28.39倍になりました。
さすがに10000トレードするとすごいですね。1969倍になります。
ランダム関数は、毎回表示結果が変わるので、何度も試すことができます。
実際に自分でエクセルに関数を入力してやってみると面白いです。
とういことで、10000トレードをさらに10回繰り返してみました。
おまけで「平均値、中央値、最大値、最小値」も計算してみました。
結果をどうぞっ！！！
勝率60%のトレードは、やはりすごいですね！！
何度やっても成功します。
10回の中で一番成績が悪かった「最小値」を見ても順調に資金が増えていることが分かります。
100回トレードして104000円、1.04倍、1000回トレードして7.8倍、10000回トレードすると1596倍になります。
FXにおいて「勝率60%」のやり方を見つけることがいかに大事なことかお分かりいただけるかと思います。
また、初期資金や損失許容率、勝率、リスクリワードを変えることで何通りもの違ったシミュレート結果を得ることができます。
試しに次のような条件に変えて結果を表示させてみます。
初期資金 500000円
損失許容率4%(スタートは20Lot、最大Lotを100Lotとして計算していきます。）
リスクリワード１：１
勝率55%をエクセルのランダム関数で求めて10000回繰り返す
初期資金を多めに、損失許容率を少し攻めの4%に設定してみました。
勝率は少し下げて55%です。
さて、結果はどうなるでしょうか。
結果は…勝率60%損失許容率2%のときとさほど変わらないですね。
試しにさらに10回シミュレートを繰り返してみます。
10000回トレードするとだいたい20000倍くらいになります。
勝率60%損失許容率2%よりも勝率55%損失許容率4%の方が少しだけ成績がいいことが分かります。
エクセル大先生、さまさまです。
【Lotの考え方】Lotを固定した場合とLotを資産の割合で変動させた場合の違いをシミュレートする
FXで資産運用を本気でやりたいと思っているなら、Lotの考え方がとても重要になってきます。
Lotを適当に設定すると資産が思うように増えません。
固定Lotと変動Lotは資産がどのように推移していくのでしょうか。
今回は、Lotを固定した場合とLotを変動させた場合の資産の推移をシミュレートしてみます。
まずはそろえる条件です。
初期資金100000円
リスクリワード１：１
勝率60%をエクセルのランダム関数で求めて10000回繰り返す
分かりやすく次の４パターンを比べてみましょう。
Lotを2Lotに固定した場合
Lotを5Lotに固定した場合
損失許容率2%(スタートは2Lot、最大Lotを100Lotとして計算していきます。）
損失許容率5%(スタートは5Lot、最大Lotを100Lotとして計算していきます。）
この４つを比べていきます。
果たして違いがでるのでしょうか！！？
まずは2Lot固定の場合と、5Lot固定の場合です。（勝敗は2Lot固定の場合と5Lot固定の場合、同じになっています。）
結果はこちら。
| リワード | 1000 | 勝率 | 60% | 初期資金 | 100000 | 初期資金 | 100000 |
| リスク | -1000 | 勝ち | 60 | 許容損失率 | 0.02 | 許容損失率 | 0.05 |
| 負け | 40 | 許容損失額 | =F1*F2 | 許容損失額 | =H1*H2 | ||
| 2Lot固定の場合 | 5Lot固定の場合 | ||||||
| 回数 | ランダム | 勝敗 | リスク リワード | 適正Lot | 合計資産 | 適正Lot | 合計資産 |
| 1 | =RAND()*100 | =IF(B6>=$D$3,”〇”,”×”) | =IF(C6=”〇”,$B$1,$B$2) | 2 | =F1+D6*E6 | 5 | =H1+D6*G6 |
| 2 | =RAND()*100 | =IF(B7>=$D$3,”〇”,”×”) | =IF(C7=”〇”,$B$1,$B$2) | 2 | =F6+D7*E7 | 5 | =H6+D7*G7 |
| 3 | =RAND()*100 | =IF(B8>=$D$3,”〇”,”×”) | =IF(C8=”〇”,$B$1,$B$2) | 2 | =F7+D8*E8 | 5 | =H7+D8*G8 |
3回目を下に10000回目までコピーすればOKです。
今回もランダム関数を使っています。
まずはじめに、ランダム関数で0～100の数字を作ります。
次に、作った数字が40以上であれば〇を返します。それ以外の場合は×を返します。
もし〇であればリワードのもとの数字「1000」をもってきます。
もし×であればリスクのもとの数字「-1000」をもってきます。
今回の場合、適正Lotは「２」と「５」で固定です。
最後に、資産＋リスクリワードのもとの数×Lotの計算をします。
これを10000回繰り返しています。
100回トレードして2Lot固定が1.2倍、5Lot固定が1.5倍になっています。
1000回トレードすると2Lot固定が4.56倍、5Lot固定が9.9倍になっています。
10000回トレードすると2Lot固定が388.4倍、5Lot固定が956倍になっています。
これだけでもすごい結果ですね。
それでは、Lotを変えた場合を見てみましょう。
トレード100回ではそこまで大きな変化がありません。
しかし、トレード100回目から1000回目の間にかなりの差が開いています。
1000回トレード時点で損失許容率2%の方は21倍、損失許容率5%の方は122倍になっています。
トレード10000回目には損失許容率2%の方は1718倍、損失許容率5%の方は1836倍です。
今回の結果を表にまとめてみましょう。
| トレード回数 | 2Lot固定 | 5Lot固定 | 損失許容率 2% | 損失許容率 5% |
| 10 | 1.04倍 | 1.1倍 | 1.04倍 | 1.1倍 |
| 100 | 1.20倍 | 1.5倍 | 1.04倍 | 1.44倍 |
| 1000 | 4.56倍 | 9.9倍 | 21.0倍 | 122.76倍 |
| 10000 | 38.84倍 | 95.6倍 | 1718.52倍 | 1836.76倍 |
やはり、この結果から分かるように損失許容率は、変化させていった方が資金が増えやすいことが分かります。
Lotの考え方については下記の記事で詳しく解説しています。
よかったら参考にしてみてください。
【なぜ損失許容率は2%なの？】勝率とリスクの関係をエクセルでシミュレートする
一般的に「損失許容率は2%がいいですよ」と言われています。
なぜ損失許容率は2%なの？
10%とか20%とかじゃダメなの？
一番利益率が高い損失許容率を教えて！！
こんな疑問を解決していくれるのが、勝率とリスクの関係です。
リスクとは１回のトレードでどれだけ損失を許容するかということです。
「損失許容率」や「損失許容額」と言われているものです。
この勝率とリスクという２つの関係をエクセルで計算すれば、損失許容率についてすっきりと理解することができます。
百聞は一見にしかずということで、まずは勝率とリスクの関係の表から見てみましょう。（この表はリスクリワード１：１のとき）
| 勝率 | 50 | 51 | ||
| トータル | 100 | 100 | ||
| 勝ち | =D1 | =E1 | ||
| 負け | =D2-D3 | =E2-E3 | ||
| 損失許容率 | リワード | リスク | ||
| 1% | 1.01 | 0.99 | =$B6^D$3*$C6^D$4 | =$B6^E$3*$C6^E$4 |
| 2% | 1.02 | 0.98 | =$B7^D$3*$C7^D$4 | =$B7^E$3*$C7^E$4 |
この勝率とリスクの関係の表のきもとなる部分は「=$B6^D$3*$C6^D$4」のところです。
これはリワードを勝ち回数分かけています。つまり1.01の50乗をしているということです。
そしてリスクを負け回数分かけています。つまり0.99の50乗をしています。
そして、勝ちで出た数値と負けで出た数値をさらにかけています。
計算式で表すと1.01^50*0.99^50となります。
「=$B6^D$3*$C6^D$4」は必要な行列が固定されているので、右側と下側にコピーすればOKです。
横軸は「勝率」を表している
まず表の見方なんですが、上は「勝率」が表示されています。
| 勝率 | 50 | 51 | ||
| トータル | 100 | 100 | ||
| 勝ち | =D1 | =E1 | ||
| 負け | =D2-D3 | =E2-E3 |
このように計算式を入れて、右のほうにコピーすれば出来上がりです。
僕は、勝率100%の結果まで知りたかったので100までコピーしました。
例えば勝率50%のときは100回トレードして50回勝って、50回負けるということですね。
勝率60%は100回トレードして60回勝って、40回負けるということです。
縦軸は「損失許容率」を表している
そして、表の左側に損失許容率が表示されています。
| 勝率 | ||
| トータル | ||
| 勝ち | ||
| 負け | ||
| 損失許容率 | リワード | リスク |
| 1% | 1.01 | 0.99 |
| 2% | 1.02 | 0.98 |
| 3% | 1.03 | 0.97 |
ここは計算式を入れてもできますし、数字を下の方にコピーしてもできます。
損失許容率が大きくなったらどうなるか知りたい方は下の方にコピーしていけばOKです。
僕は、損失許容率が100%のときにどうなるか気になったので、100%までコピーしました。
これは例えば損失許容率2%のとき、勝ったら資産が1.02倍になって、負けたら0.98倍になりますということです。
損失許容率が5%のときは、勝ったら1.05倍になって、負けたら0.95倍になるということです。
横軸は「勝率」縦軸は「損失許容率」。全体を俯瞰すると見えるもの。
横軸と縦軸の見方が分かったところで、もう一度全体を見てみましょう。
この表を見て気づくことはいろいろとあるので分析していきましょう。
この表は「100回トレードしたときに資産が何倍になっているか」を表している
まず、表の数値は何を表しているかというと、「100回トレードしたときに資産が何倍になっているか」を表しています。
例えば、勝率51%で損失許容率が2%のとき、「1.02」となっています。
これは勝率51%で損失許容率が2%のトレードを100回繰り返すと、資産が1.02倍になることを表しています。
勝率52%で損失許容率が4%で100回トレードをすると資産が1.083倍になります。
ここであることに気づきます。
勝率50%のところを見てみると、すべて１以下になっています。
「勝率50%だと勝てない」ということです。（リスクリワード１：１の場合）
損失許容率が1%の場合で100回トレードしたとしても0.995倍になってしまいます。
リスクリワードが１：１の場合は、勝率を51%以上にする必要があります。
利益率が一番高いのはどこ？
背景がピンク色になっているところが一番利益率が高いです。
具体的には次の数字。
勝率51% 損失許容率2% → 1.02倍
勝率52% 損失許容率4% → 1.083倍
勝率53% 損失許容率6% → 1.197倍
勝率54% 損失許容率8% → 1.378倍
勝率55% 損失許容率10% → 1.6倍
勝率60% 損失許容率20% → 7.49倍
7.49倍は魅力的ですよね！
ただ、損失許容率20%でよくない？と考えると破産する可能性が高くなります。
「じゃあ損失許容率20%でいいんじゃない？」と考えると破産する訳
確かに、「勝率60% 損失許容率20%」はトレードを100回すると資産が7.49倍になってすごいです。しかし、損失許容率20%のとき勝率50%だった場合を表で確認してみてください。
0.13倍になっています。
これはつまり、損失許容率が20%のときに勝率が50%になってしまった場合、資産は約10分の1になってしまうということです。
もし損失許容率2%でトレードをしていたといたらどうでしょうか。
勝率50%、損失許容率2%を表で確認すると、資産は0.98倍。もともとの資産とあまり変わりがありません。
これが「損失許容率は2%にした方がいい」と言われている理由です。
結局、おすすめの損失許容率はいくつ？
自分のトレードの記録をつけているでしょうか。
トレード記録があれば、勝率が割り出せます。
勝率が分かれば、一番適切な損失許容率で勝負することが可能です。
もしトレードを始めたばかりであれば「損失許容率2%」がおすすめです。
勝率が上がってきたら、それに合わせて「損失許容率」をレベルアップさせていきましょう。
厳密に言えばトレードのやり方（手法）によって勝率は変わってきます。
勝率によって損失許容率を変えていくのが、一番利益率が高いトレードになります。
まとめ 「複利の力」はエクセルで見える化する
一度エクセルで式を入力してしまえば、ずっと使うことができます。
何万回、何十万回というシミュレートも、エクセルなら一瞬で計算してくれます。エクセル大先生、さまさまです。
資産運用をシミュレートするときに役立ったエクセル関数はこの13個。
| 順位 | エクセル関数 | 役割 |
| 1 | 四則演算 =1+1 =1-1 =1*1 =1/1 | エクセル関数を使うときには必ず頭に「=」をつける 計算式には数値も入れることができるし、セルを選択することもできる 「+」…足し算の結果を求める 「-」…引き算の結果を求める 「*」…かけ算の結果を求める 「/」…わり算の結果を求める |
| 2 | =SUM(数値) | 数値の合計を求める |
| 3 | =AVERAGE(数値) | 数値の平均値を求める |
| 4 | =MEDIAN(数値) | 数値の中央値を求める 中央値とはデータの真ん中の値ということ データの中に大きく外れた値があるときに平均値だとその値に影響されてしまうが、中央値ならちょうど真ん中の数値を把握できる |
| 5 | =MAX(数値) | 最大の数値を求める |
| 6 | =MIN(数値) | 最小の数値を求める |
| 7 | =RAND() | 0~1のランダムな数値を返す ランダムな数値を使ってシミュレートしたいときに使う |
| 8 | =ABS(数値) | 数値の絶対値を返す 絶対値とは、数値から符号（+や-）を除いた数そのものの大きさのこと |
| 9 | =IF(論理式,真の場合,偽の場合) | 「もしも…の場合はA、…の場合はB」と値を変えることができる 例えば、勝ったら「1000」、負けたら「-1000」などを求めることができる |
| 10 | =ROUND(数値,桁数) | 指定した桁数までを表示するように四捨五入する |
| 11 | =10^2 | ^（キャレット）を使うと〇条を計算することができる 10^2は、10の2乗で100になる =POWER(数値,指数)関数を使っても求められる |
| 12 | =COUNT(範囲) =COUNTA(範囲) =COUNTIF(範囲,検索条件) =COUNTBLANK(範囲) | COUNT…数値を含むセルの個数を求める COUNTA…空白ではないセルの個数を求める COUNTIF…条件に当てはまるセルの個数を求める COUNTBLANK…空白のセルの個数を求める 例えば、勝敗を「〇」と「×」で入力していた場合、勝率を求めるときにCOUNTIFを使えば「〇」と「×」の個数を一瞬で計算してくれる |
| 13 | =INDEX(範囲,行番号,列番号) | 範囲の中の指定された行と列が交差する位置にあるセルを返す 例えば、100回トレードした結果は？1000回トレードした結果は？という100回目、1000回目のデータを取り出すときに使える |
今回のシミュレートで使っていない関数もありますが、その解説はまた別の記事でやります。
エクセルなら自分の資産が推移していくイメージを具体的につかむことができます。
また、エクセル関数を使えるようになれば、自分の考えた仮説を検証するのに役立ちます。
ユーロドルは市場ごとにどれくらいの値幅があるんだろう？時間帯による優位性を過去検証で確かめたい。他の通貨ペアも調べてみたい。
資産に応じた適正Lotを自動で計算したい。
あるトレード手法の勝率は〇%くらいだから、資産がどんな風に増えていくかシミュレートしてみたい。損失許容率はどれくらいに設定した方がいいか知りたい。
こんな疑問が生まれたとしても、エクセルで計算すれば一発で分かります。
資産運用では「複利の力」を味方につける考え方が必要です。
その補助的なツールとしてエクセルは役に立ちます。
「複利の力」を目に見える形で、具体的な数値としてとらえることができます。
【無料プレゼント】LINEに登録すると「投資に役立つデータ集」が無料でもらえる✨
- 資産を爆発的に増やす方法が知りたい
- 青天井に稼ぎたい・収入の限界を突破したい
- FX・投資の具体的な勝ち方を知りたい
- 再現性のあるトレード方法が知りたい
- 高勝率のトレード方法が知りたい
こういった方のために、僕が心を込めて作りました。
投資脳構築についての質問は随時募集中✨
YouTube、LINE、X、ブログでは、
投資脳を構築するための情報を発信しています。
もし質問があれば、
YouTubeコメント、LINE、X（旧Twitter）にて直接聞いてください。
◆YouTube
https://www.youtube.com/@toushikurage
◆LINE：「投資脳構築セミナー」「投資に役立つデータ集」を無料プレゼント！！
◆X（旧Twitter）
https://twitter.com/toushikurage
◆ブログ
僕は、これからも、
投資脳を構築するための情報を発信し続けていきます。
一緒に学んでいきましょう。
コメント